;Done: replace variable names with working names (%wootness --> %1)
;Here is the table:
;gloves=%0
;cornvisit=%1
;kitchenkey=%2
;dishvisit=%3
;dogvisit=%4
;rope=%5
;crazy=$0



*define

linepage
savename "`Save", "`Load", "`Slot "
versionstr "The Room","by OrR 02-2006"
rmenu "`Skip To Next Choice",skip,"`Hide Text Window",windowerase,"`Save",save,"`Load",load,"`Log Mode",lookback,"`Return To Title",reset
effect 1,2,500;left shutter
effect 2,5,500;down shutter
effect 3,8,1000;upwards curtain
effect 4,9,1000;downwards curtain
effect 5,10,1000;pixel crossfade

game

*start

*startmenu
mp3loop "wootness.mp3"
bg "theroom.jpg",3
locate 10,12
select "`Start",*gamestart,"`Load",*gameload

*gameload
systemcall load
goto *startmenu

*gamestart
bg black,4
stop
setwindow 19,330,32,6,19,19,0,1,20,1,1,#999999,9,320
mp3loop "wootness.mp3"
`Suddenly you wake up. What was happening? Where are you? WHO are you?! What is this place?
print 1
`Slowly you open your eyes...
print 1
bg "kitchen.jpg",3
`Seems like a kitchen...
print 1
`What do you want to do?
print 1



*kitchen
select "`Eat an apple",*apple,"`Look inside the cupboard",*cupboard,"`Turn on the water",*water,"`Ride a zebra",*zebra,"`Read the paper",*paper,"`Open the door",*kitchendoor,"`Why?",*why


*apple
if $0="r" mov $0,"a"
notif $0="r" mov $0,"x"
select "`Eat an apple",*appleeat,"`Don't eat an apple",*kitchen
*appleeat
if %0=1 goto *appleg
notif %0=1 goto *appled
*appled
`You pick up an apple and eat it.
`Suddenly you feel something inside your stomach...
Stop
`In the last seconds of your life you see huge tentacles growing out of your body...
mp3loop "wootness.mp3"
bg "death.jpg",4
`You have died.
reset
*appleg
`You pick up an apple with your gloves. Suddenly huge tentacles grab you and you are pulled into the apple!
goto *organic


*cupboard
mov $0,"c"
`You look inside the cupboard. There isn't much here...
`What do you do?
select "`Search the cornflakes",*cornflakes,"`Search the knives",*knives,"`Search behind the dishes",*dishes,"`Nothing",*kitchen

*cornflakes
if %1=1 goto *corn1
notif %1=1 goto *corn0
*corn0
`There is nothing here...
mov %1,1
goto *cupboard
*corn1
`Hey, what is this? There is a key you didn't find the first time around!
mov %1,2
mov %2,1
goto *cupboard

*knives
`You search through the knives. They have many different shapes and forms... Suddenly you cut yourself! Damn!
`As you see the blood shoot out of your finger you loose consciousness and fall face forward into the knives.
stop
mp3loop "wootness.mp3"
bg "death.jpg",4
`You have died.
reset

*dishes
if %3=1 goto *dish1
notif %3=1 goto *dish0
*dish1
`There is nothing left here...
goto *cupboard
*dish0
`There are some gloves behind the dishes! They could come in handy...
mov %3,1
mov %0,1
goto *cupboard


*water
`You turn on the water.
`Hmm, the drain seems to be blocked...
`After a while you try to turn off the water but it does not work! The tap seems to be broken!
`You stand there and can't do anything against the masses of water slowly pouring into the room. The water seems to be accumulating, it does not flow out through the door.
`After only minutes, you have to start swimming because you cannot stand anymore.
bg black,2
`A few minutes later the water has almost reached the ceiling and it is becoming hard to breathe!
`Now you are completely under water and can't do anything. You wonder what will happen...
`Suddenly the ceiling bursts open and releases you into the room above.
goto *scifi


*zebra
if $0="a" mov $0,"z"
notif $0="a" mov $0,"x"
`What zebra?! There is no zebra around!
goto *kitchen


*paper
if $0="c" mov $0,"r"
notif $0="c" mov $0,"x"
`You read the paper that is lying around on the table.
`The date of the paper is: 12.3.4567
`What the hell? This must be a joke, right?
`The headline reads: "Another battle against the robots won!"
`Damn, this can't be true! What on earth happened to you?
goto *kitchen


*kitchendoor
if %2=1 goto *dooropen
notif %2=1 goto *doorclosed
*doorclosed
`The door is closed. You need a key to open it.
goto *kitchen
*dooropen
`You use the key you found. It is the right one!
`You open the door and step into the next room.
goto *livingroom


*why
if $0="z" goto *whysolved
notif $0="r" goto *because
*because
mov $0,"x"
`Because!
goto *kitchen
*whysolved
`Suddenly the world around you begins to flicker. What the hell is this?
Stop
quake 10,2000
bg black,5
`Something doesn't smell right...
goto *crazy



*scifi
mp3loop "wootness.mp3"
bg "3cross.jpg",3
`You get out of the water and on some kind of bridge.
`The room around you looks weird. What are all those wires? And the blinking lights? This looks completely different from the normal kitchen below. It reminds you of Sci Fi TV shows.
`You look around. There isn't much you can do.
`You can see three ways out of the room. One seems to be guarded by a roboter dog, the other by a roboter cat and the third seems to be unguarded and leads onto some kind of bridge.
*3cross
select "`Go the dog-way",*dogway,"`Go the cat-way",*catway,"`Go the bridge-way",*bridgeway

*dogway
if %4=1 goto *dogdeath
notif %4=1 goto *doglive
*dogdeath
`You slowly approach the robo-dog as before. And as last time, he suddenly attacks!
`You search for something to defend yourself with.
`But it's too late. The robo-dog rips your body to pices with hisd fangs.
Stop
mp3loop "wootness.mp3"
bg "death.jpg",4
`You have died.
reset
*doglive
`You approach the robo-dog.
`It starts to growl as you come nearer.
`Suddenly, it attacks you!
`Driven by instinct you grab a pice of metal you find on the floor and throw it at the dog.
`The dog catches it with it's teeth and crashes it to pices but that gives you enough time to pass on into the next room.
bg "rope.jpg",1
`The dog does not seem to follow you.
`There isn't much usefull stuff here... And no other way to go but back.
`You only see a rope on the floor.
select "`Take the rope with you",*ropetake,"`Don't take the rope with you",*norope
*norope
`You don't take the rope with you. What use would it have?
goto *ropecont
*ropetake
mov %5,1
You take the rope with you. It might be usefull later...
*ropecont
`Now, how to get back without being hurt by the dog?
`It's facing the other direction and does not seem to be interested in you.
`You run, jump on it's head and are back in the middle of the room with the three ways.
goto *3cross

*catway
`You choose the way that is guarded by the robo-cat.
`As you aproach it, it starts to make weird noises.
`You get nearer and nearer. Suddenly the cat attacks!
`It cuts your belly open with it's sharp razor claws. You fall into the water below.
Stop
mp3loop "wootness.mp3"
bg "death.jpg",4
`You have died.
reset

*bridgeway
bg "bridge.jpg",1
`You slowly walk over the bridge.
`Where will this lead you?
`You can see another door at the end of the bridge.
`It is too dark to make out what the bridge crosses over.
`Suddenly you hear a crack.
`The bridge is breaking down under your feet!
bg "bridgebreak.jpg",2
if %5=1 goto *bridgerope
notif %5=1 goto *bridgefall
*bridgerope
`A quick reflex makes you throw your rope at one of the pillars at the end of the bridge.
`Which pillar do you throw the rope at?
select "`Throw it at the left pillar", *pillarbreak, "`Throw it at the right pillar", *bridgeend
*pillarbreak
`The pillar breaks under your weight.
*bridgefall
`You fall down into the darkness.
`Suddenly you hit something hard that breaks.
`Then you fall onto the floor of a room.
goto *livingroom
*bridgeend
`You reach the end of the bridge by climbing up the wall with the rope.
`There is another door here.
`You open it and enter the next room.




*livingroom



*organic



*crazy


`Sorry, the demo ends here. More Later.
reset





end